POST

Editing whitespace-separated config files with cfengine

August 25, 2010

	# Sets the RHS of configuration items in the file of the form
	# LHS RHS
	# If the line is commented out with #, it gets uncommented first.
	# Adds a new line if none exists.
	# The argument is an associative array containing v[LHS]="rhs"

	# Based on set_variable_values from cfengine_stdlib.cf, modified
	# by Diego Zamboni to use whitespace as separator, and to handle
	# commented-out lines.
	bundle edit_line set_config_values(v)
	{
	vars:
	"index" slist => getindices("$(v)");

	# Be careful if the index string contains funny chars
	"cindex[$(index)]" string => canonify("$(index)");

	field_edits:

	# If the line is there, but commented out, first uncomment it
	"#+$(index)\s+.*"
	edit_field => col("\s+","1","$(index)","set");

	# match a line starting like the key something
	"$(index)\s+.*"
	edit_field => col("\s+","2","$($(v)[$(index)])","set"),
	classes => if_ok("not_$(cindex[$(index)])");

	insert_lines:

	"$(index) $($(v)[$(index)])",
	ifvarclass => "!not_$(cindex[$(index)])";
	}