Automatically creating tasks from email in Outlook

Please note: I am no longer using Windows nor Outlook, so unfortunately I cannot offer any help with problems you encounter using these scripts and techniques.

Over the last few days I have been redoing my GTD-under-Outlook setup, based on the instructions available in the "GTD and Outlook" guide from DavidCo (I will write more about my setup later). One of the tricks the guide suggest is creating a mail rule on outgoing mail, which scans the message body for a special tag (/wf or *wf* are suggested) and automatically adds the message to the @WAITING FOR email folder.

As a bonus, I modified the script so that any text you type after the /wf tag becomes the title of the newly-created task (if you don't type anything, the subject of the email message is used). This makes it easier to give your @WAITING FOR items a good, descriptive title upfront.

So here are the detailed steps of what you need to do:

1. In the Developer tab, click on "Visual Basic", which opens the VBA development environment, and unless you already have other macros installed, should give you a blank window. 
   
   
2. Paste the code:
   

   	' How to use it: see http://zzamboni.org/post/automatically-creating-tasks-from-email-in-outlook
   	' Diego Zamboni, March 16, 2011
   	' Set the string comparison method to Text ("AAA" = "aaa").
   	Option Compare Text
   	' Based originally on code from http://www.outlookcode.com/codedetail.aspx?id=959, modified by Diego Zamboni
   	Sub MakeWaitingForTaskWithAttachmentFromCurrentMessage(MyMail As Outlook.MailItem)
   	Dim strID As String
   	Dim olNS As Outlook.NameSpace
   	Dim olMail As Outlook.MailItem
   	Dim objTask As Outlook.TaskItem
   	Dim categories As String
   	Dim addRecipient As Boolean
   	Dim regex
   	Dim matches, customSubject, subject
   	' Configuration options
   	categories = "@WAITING FOR"
   	addRecipient = True
   	strID = MyMail.EntryID
   	Set olNS = Application.GetNamespace("MAPI")
   	Set olMail = olNS.GetItemFromID(strID)
   	Set objTask = Application.CreateItem(olTaskItem)
   	objTask.Attachments.Add MyMail
   	Set regex = CreateObject("vbscript.regexp")
   	regex.Pattern = "/wf (.*)"
   	regex.IgnoreCase = True
   	regex.Global = True
   	Set matches = regex.Execute(olMail.Body)
   	If matches.Count <> 0 Then
   	customSubject = matches(0).submatches(0)
   	Else
   	customSubject = ""
   	End If
   	If customSubject <> "" Then
   	subject = customSubject
   	Else
   	subject = olMail.subject
   	End If
   	With objTask
   	If addRecipient Then
   	.subject = olMail.Recipients.Item(1) & ": " & subject
   	Else
   	.subject = subject
   	End If
   	.categories = categories
   	.Body = olMail.Body
   	End With
   	objTask.Save
   	Set objTask = Nothing
   	Set olMail = Nothing
   	Set olNS = Nothing
   	End Sub
   	' Wrapper that gets the current item and calls the previous function, to use as a macro
   	Sub MakeWaitingForTaskWithAttachmentFromCurrentMessageMacro()
   	Dim curMail As Outlook.MailItem
   	Set curMail = GetCurrentItem()
   	Call MakeWaitingForTaskWithAttachmentFromCurrentMessage(curMail)
   	End Sub
   	' From http://www.outlookcode.com/codedetail.aspx?id=50
   	Function GetCurrentItem() As Object
   	Dim objApp As Outlook.Application
   	Set objApp = CreateObject("Outlook.Application")
   	On Error Resume Next
   	Select Case TypeName(objApp.ActiveWindow)
   	Case "Explorer"
   	Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
   	Case "Inspector"
   	Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
   	Case Else
   	' anything else will result in an error, which is
   	' why we have the error handler above
   	End Select
   	Set objApp = Nothing
   	End Function

   view raw outlook_MakeWaitingForTaskWithAttachmentFromCurrentMessage.bas hosted with ❤ by GitHub
3. The code includes both the "script" to use in an email rule (which receives the email message as argument) and a macro (without arguments) so that you can run it manually from the Macros menu (also in the Developer tab). Try it out - select an email message, choose the macro from the Macros menu, and check that a new task in the @WAITING FOR category is created, with the original message as an attachment. 
4. If needed, modify the category to which the task is assigned (or leave it empty to create an uncategorized task). 
5. The code by default adds the recipient of the message to the beginning of the task title, separated by a colon (of the form "recipient: subject"). This makes it easier to see pending items per person (and, if you use the 2Do iPhone app, it automatically groups entries by the text before the colon, which makes it even easier to process. If you don't want this, modify the value of addRecipient to "False".
6. To ensure that the macros run correctly after restarting Outlook, you have to sign it digitally, following the instructions here: http://office.microsoft.com/en-us/outlook-help/digitally-sign-a-macro-project.... Create a self-signed certificate and use it for signing the macro package. I had to restart Outlook for the digital signature to take proper effect. 
7. Create the rule that will invoke the new subroutine on appropriate incoming email message(to create a new rule open the Home tab, then the Rules menu, then "Manage Rules and Alerts", create a blank rule for incoming messages, choose the appropriate criteria, and click on the underlined parts to define the parameters). These are the criteria I used: my rule operates on incoming mail from any of my accounts (so that only I can create Waiting For tasks for myself) and that contains "/wf" or "/*wf*/" in the body (in practice I always use /wf). I choose to automatically move the message to a local Outlook file (I have a pretty restrictive server quota), but you may want to skip this step. I also mark the message as read automatically, and of course I invoke the script created in the previous steps. 
   
8. Test it out. Send a message to yourself that contains /wf in the body. What I do in practice is that I include the /wf at the end of the message, and make it 1-point font and white so it's invisible to most people, but still detectable by the filter. After the message arrives you should see the new task appear in the appropriate category, containing the original message as an attachment. If you want to give the task a custom title instead of using the email subject, type it after the /wf, like this: "/wf Response about foo bar". The email recipient will still be added when you specify a custom title, unless you have disabled it in the code (see step 5).

Of course, when using this to flag messages sent to other people, you need to make sure you either automatically cc yourself (if you have created the rule on incoming mail), or that you create it on outgoing mail. I have not tested this case, but the "run a script" option is there as well for outgoing messages, so I don't see a reason why it should not work.